[m-rev.] diff: speed up determinism analysis a bit

Zoltan Somogyi zs at unimelb.edu.au
Tue Apr 24 19:15:27 AEST 2012


Avoid some redundant work during determinism analysis. This diff speeds up
tools/speedtest by just shy of 0.7%.

compiler/det_analysis.m:
	Instead of (a) getting a list of procedures in the module and then
	(b) classifying them into three categories, do both jobs at once.
	This avoids some redundant traversals and map lookups, and avoids
	the creation of an intermediate data structure.

compiler/instmap.m:
	Instead of converting a set into a list and iterating over that list
	to check that elements of the set have a given property, iterate over
	the set elements directly.

	Put the arguments of a predicate in a more logical order.

compiler/det_util.m:
	Conform to the change in instmap.m.

compiler/set_of_var.m:
	Provide the all_true predicate needed by det_util.

library/*set*.m:
	In every module that implements sets, provide an all_true predicate.

NEWS:
	Mention the new predicates in the library.

Zoltan.

cvs diff: Diffing .
Index: NEWS
===================================================================
RCS file: /home/mercury/mercury1/repository/mercury/NEWS,v
retrieving revision 1.607
diff -u -b -r1.607 NEWS
--- NEWS	2 Apr 2012 03:58:52 -0000	1.607
+++ NEWS	24 Apr 2012 09:11:02 -0000
@@ -8,9 +8,10 @@
   set_unordlist.singleton_set/2 so that it conforms with the order in the
   other set modules.
 
-* All the modules that operate on sets now have a new predicate insert_new.
-  If the item is not already in the set, it inserts the item, otherwise
-  it fails.
+* All the modules that operate on sets now have two new predicates.
+  One is insert_new: if the item is not already in the set, it inserts
+  the item, otherwise it fails. The other is all_true: it succeeds if
+  and only if all elements in the set pass a test.
 
 * The argument order of the following predicates has been changed so as to
   make them more conducive to the use of state variable notation:
cvs diff: Diffing analysis
cvs diff: Diffing bindist
cvs diff: Diffing boehm_gc
cvs diff: Diffing boehm_gc/Mac_files
cvs diff: Diffing boehm_gc/cord
cvs diff: Diffing boehm_gc/cord/private
cvs diff: Diffing boehm_gc/doc
cvs diff: Diffing boehm_gc/extra
cvs diff: Diffing boehm_gc/include
cvs diff: Diffing boehm_gc/include/extra
cvs diff: Diffing boehm_gc/include/private
cvs diff: Diffing boehm_gc/libatomic_ops
cvs diff: Diffing boehm_gc/libatomic_ops/doc
cvs diff: Diffing boehm_gc/libatomic_ops/src
cvs diff: Diffing boehm_gc/libatomic_ops/src/atomic_ops
cvs diff: Diffing boehm_gc/libatomic_ops/src/atomic_ops/sysdeps
cvs diff: Diffing boehm_gc/libatomic_ops/src/atomic_ops/sysdeps/armcc
cvs diff: Diffing boehm_gc/libatomic_ops/src/atomic_ops/sysdeps/gcc
cvs diff: Diffing boehm_gc/libatomic_ops/src/atomic_ops/sysdeps/hpc
cvs diff: Diffing boehm_gc/libatomic_ops/src/atomic_ops/sysdeps/ibmc
cvs diff: Diffing boehm_gc/libatomic_ops/src/atomic_ops/sysdeps/icc
cvs diff: Diffing boehm_gc/libatomic_ops/src/atomic_ops/sysdeps/msftc
cvs diff: Diffing boehm_gc/libatomic_ops/src/atomic_ops/sysdeps/sunc
cvs diff: Diffing boehm_gc/libatomic_ops/tests
cvs diff: Diffing boehm_gc/libatomic_ops-1.2
cvs diff: Diffing boehm_gc/libatomic_ops-1.2/doc
cvs diff: Diffing boehm_gc/libatomic_ops-1.2/src
cvs diff: Diffing boehm_gc/libatomic_ops-1.2/src/atomic_ops
cvs diff: Diffing boehm_gc/libatomic_ops-1.2/src/atomic_ops/sysdeps
cvs diff: Diffing boehm_gc/libatomic_ops-1.2/tests
cvs diff: Diffing boehm_gc/m4
cvs diff: Diffing boehm_gc/tests
cvs diff: Diffing browser
cvs diff: Diffing bytecode
cvs diff: Diffing compiler
Index: compiler/det_analysis.m
===================================================================
RCS file: /home/mercury/mercury1/repository/mercury/compiler/det_analysis.m,v
retrieving revision 1.237
diff -u -b -r1.237 det_analysis.m
--- compiler/det_analysis.m	13 Feb 2012 00:11:36 -0000	1.237
+++ compiler/det_analysis.m	24 Apr 2012 06:25:09 -0000
@@ -183,12 +183,12 @@
 :- pred global_inference_pass(module_info::in, module_info::out,
     pred_proc_list::in, bool::in, list(error_spec)::out) is det.
 
+global_inference_pass(!ModuleInfo, ProcList, Debug, Specs) :-
     % Iterate until a fixpoint is reached. This can be expensive if a module
     % has many predicates with undeclared determinisms. If this ever becomes
     % a problem, we should switch to doing iterations only on strongly
     % connected components of the dependency graph.
-    %
-global_inference_pass(!ModuleInfo, ProcList, Debug, Specs) :-
+
     global_inference_single_pass(ProcList, Debug, !ModuleInfo, [], Specs1,
         unchanged, Changed),
     trace [io(!IO)] (
@@ -2055,90 +2055,57 @@
 
 determinism_declarations(ModuleInfo, PredIds,
         DeclaredProcs, UndeclaredProcs, NoInferProcs) :-
-    get_all_pred_procs(ModuleInfo, PredIds, PredProcs),
-    segregate_procs(ModuleInfo, PredProcs,
-        DeclaredProcs, UndeclaredProcs, NoInferProcs).
-
-    % Get_all_pred_procs returns a list of all the procedure ids for that
-    % module (except class methods, which do not need to be checked since
-    % we generate the code ourselves).
-    %
-:- pred get_all_pred_procs(module_info::in, list(pred_id)::in,
-    pred_proc_list::out) is det.
-
-get_all_pred_procs(ModuleInfo, PredIds, PredProcs) :-
     module_info_get_preds(ModuleInfo, PredTable),
-    get_all_pred_procs_2(PredTable, PredIds, [], PredProcs).
+    determinism_declarations_preds(PredTable, PredIds,
+        [], DeclaredProcs, [], UndeclaredProcs, [], NoInferProcs).
 
-:- pred get_all_pred_procs_2(pred_table::in, list(pred_id)::in,
+:- pred determinism_declarations_preds(pred_table::in, list(pred_id)::in,
+    pred_proc_list::in, pred_proc_list::out,
+    pred_proc_list::in, pred_proc_list::out,
     pred_proc_list::in, pred_proc_list::out) is det.
 
-get_all_pred_procs_2(_PredTable, [], !PredProcs).
-get_all_pred_procs_2(PredTable, [PredId | PredIds], !PredProcs) :-
-    map.lookup(PredTable, PredId, Pred),
-    ProcIds = pred_info_procids(Pred),
-    fold_pred_modes(PredId, ProcIds, !PredProcs),
-    get_all_pred_procs_2(PredTable, PredIds, !PredProcs).
-
-:- pred fold_pred_modes(pred_id::in, list(proc_id)::in, pred_proc_list::in,
-    pred_proc_list::out) is det.
-
-fold_pred_modes(_PredId, [], !PredProcs).
-fold_pred_modes(PredId, [ProcId | ProcIds], !PredProcs) :-
-    !:PredProcs = [proc(PredId, ProcId) | !.PredProcs],
-    fold_pred_modes(PredId, ProcIds, !PredProcs).
-
-    % segregate_procs(ModuleInfo, PredProcs,
-    %   DeclaredProcs, UndeclaredProcs, NoInferProcs):
-    %
-    % The predicate partitions the pred_proc_ids in PredProcs into three
-    % categories:
-    %
-    % - DeclaredProcs holds the procedures that have declarations that need
-    %   to be checked.
-    %
-    % - UndeclaredProcs holds the procedures that don't have declarations
-    %   whose determinism needs to be inferred.
-    %
-    % - NoInferProcs holds the procedures whose determinism is already
-    %   known, and which should not be processed further.
-    %
-:- pred segregate_procs(module_info::in, pred_proc_list::in,
-    pred_proc_list::out, pred_proc_list::out, pred_proc_list::out) is det.
-
-segregate_procs(ModuleInfo, PredProcs, DeclaredProcs, UndeclaredProcs,
-        NoInferProcs) :-
-    segregate_procs_2(ModuleInfo, PredProcs, [], DeclaredProcs,
-        [], UndeclaredProcs, [], NoInferProcs).
+determinism_declarations_preds(_PredTable, [],
+        !DeclaredProcs, !UndeclaredProcs, !NoInferProcs).
+determinism_declarations_preds(PredTable, [PredId | PredIds],
+        !DeclaredProcs, !UndeclaredProcs, !NoInferProcs) :-
+    map.lookup(PredTable, PredId, PredInfo),
+    ProcIds = pred_info_procids(PredInfo),
+    determinism_declarations_procs(PredId, PredInfo, ProcIds,
+        !DeclaredProcs, !UndeclaredProcs, !NoInferProcs),
+    determinism_declarations_preds(PredTable, PredIds,
+        !DeclaredProcs, !UndeclaredProcs, !NoInferProcs).
 
-:- pred segregate_procs_2(module_info::in, pred_proc_list::in,
+:- pred determinism_declarations_procs(pred_id::in, pred_info::in,
+    list(proc_id)::in,
     pred_proc_list::in, pred_proc_list::out,
     pred_proc_list::in, pred_proc_list::out,
     pred_proc_list::in, pred_proc_list::out) is det.
 
-segregate_procs_2(_ModuleInfo, [], !DeclaredProcs,
-        !UndeclaredProcs, !NoInferProcs).
-segregate_procs_2(ModuleInfo, [PredProcId | PredProcIds],
+determinism_declarations_procs(_PredId, _PredInfo, [],
+        !DeclaredProcs, !UndeclaredProcs, !NoInferProcs).
+determinism_declarations_procs(PredId, PredInfo, [ProcId | ProcIds],
         !DeclaredProcs, !UndeclaredProcs, !NoInferProcs) :-
     PredProcId = proc(PredId, ProcId),
-    module_info_get_preds(ModuleInfo, Preds),
-    map.lookup(Preds, PredId, Pred),
     (
+        % Imported predicates need to be checked, but that will happen
+        % when their defining module is compiled.
+        % Since we generate the code of <in,in> unifications and class methods
+        % ourselves, they do not need to be checked.
         (
-            pred_info_is_imported(Pred)
+            pred_info_is_imported(PredInfo)
         ;
-            pred_info_is_pseudo_imported(Pred),
+            pred_info_is_pseudo_imported(PredInfo),
             hlds_pred.in_in_unification_proc_id(ProcId)
         ;
-            pred_info_get_markers(Pred, Markers),
+            pred_info_get_markers(PredInfo, Markers),
             check_marker(Markers, marker_class_method)
         )
     ->
         !:NoInferProcs = [PredProcId | !.NoInferProcs]
     ;
-        pred_info_get_procedures(Pred, Procs),
-        map.lookup(Procs, ProcId, Proc),
-        proc_info_get_declared_determinism(Proc, MaybeDetism),
+        pred_info_get_procedures(PredInfo, ProcTable),
+        map.lookup(ProcTable, ProcId, ProcInfo),
+        proc_info_get_declared_determinism(ProcInfo, MaybeDetism),
         (
             MaybeDetism = no,
             !:UndeclaredProcs = [PredProcId | !.UndeclaredProcs]
@@ -2147,8 +2114,8 @@
             !:DeclaredProcs = [PredProcId | !.DeclaredProcs]
         )
     ),
-    segregate_procs_2(ModuleInfo, PredProcIds, !DeclaredProcs,
-        !UndeclaredProcs, !NoInferProcs).
+    determinism_declarations_procs(PredId, PredInfo,
+        ProcIds, !DeclaredProcs, !UndeclaredProcs, !NoInferProcs).
 
     % We can't infer a tighter determinism for imported procedures or for
     % class methods, so set the inferred determinism to be the same as the
Index: compiler/det_util.m
===================================================================
RCS file: /home/mercury/mercury1/repository/mercury/compiler/det_util.m,v
retrieving revision 1.55
diff -u -b -r1.55 det_util.m
--- compiler/det_util.m	16 Aug 2011 03:26:30 -0000	1.55
+++ compiler/det_util.m	24 Apr 2012 06:58:17 -0000
@@ -215,8 +215,9 @@
 
 det_no_output_vars(Vars, InstMap, InstMapDelta, DetInfo) :-
     det_info_get_module_info(DetInfo, ModuleInfo),
-    instmap_delta_no_output_vars(InstMap, InstMapDelta, Vars,
-        DetInfo ^ di_vartypes, ModuleInfo).
+    VarTypes = DetInfo ^ di_vartypes,
+    instmap_delta_no_output_vars(ModuleInfo, VarTypes, InstMap, InstMapDelta,
+        Vars).
 
 det_info_add_error_spec(Spec, !DetInfo) :-
     det_info_get_error_specs(!.DetInfo, Specs0),
Index: compiler/instmap.m
===================================================================
RCS file: /home/mercury/mercury1/repository/mercury/compiler/instmap.m,v
retrieving revision 1.73
diff -u -b -r1.73 instmap.m
--- compiler/instmap.m	16 Aug 2011 03:26:31 -0000	1.73
+++ compiler/instmap.m	24 Apr 2012 06:53:18 -0000
@@ -272,12 +272,13 @@
 :- pred instmap_delta_delete_vars(list(prog_var)::in,
     instmap_delta::in, instmap_delta::out) is det.
 
-    % `instmap_delta_no_output_vars(Instmap, InstmapDelta, Vars, ModuleInfo)'
-    % is true if none of the vars in the set Vars could have become more
-    % instantiated when InstmapDelta is applied to Instmap.
+    % instmap_delta_no_output_vars(ModuleInfo, VarTypes, InstMap,
+    %   InstMapDelta, Vars)
+    % is true if none of the vars in Vars can become more instantiated
+    % when InstMapDelta is applied to InstMap.
     %
-:- pred instmap_delta_no_output_vars(instmap::in, instmap_delta::in,
-    set_of_progvar::in, vartypes::in, module_info::in) is semidet.
+:- pred instmap_delta_no_output_vars(module_info::in, vartypes::in,
+    instmap::in, instmap_delta::in, set_of_progvar::in) is semidet.
 
     % merge_instmap_delta(InitialInstMap, NonLocals,
     %   InstMapDeltaA, InstMapDeltaB, !ModuleInfo):
@@ -312,10 +313,10 @@
 
 %-----------------------------------------------------------------------------%
 
-    % instmap_delta_apply_sub(Must, Renaming, InstmapDelta0, InstmapDelta):
+    % instmap_delta_apply_sub(Must, Renaming, InstMapDelta0, InstMapDelta):
     %
-    % Apply the variable renaming Renaming to InstmapDelta0 to get the new
-    % instmap_delta InstmapDelta.  If there is a variable in InstmapDelta0
+    % Apply the variable renaming Renaming to InstMapDelta0 to get the new
+    % instmap_delta InstMapDelta.  If there is a variable in InstMapDelta0
     % which does not appear in Renaming, it is ignored if Must is set to
     % need_not_rename, otherwise it is an error.
     %
@@ -1227,19 +1228,23 @@
 %-----------------------------------------------------------------------------%
 %-----------------------------------------------------------------------------%
 
-instmap_delta_no_output_vars(_, unreachable, _, _, _).
-instmap_delta_no_output_vars(InstMap0, reachable(InstMapDelta), Vars, VT, M) :-
-    set_of_var.to_sorted_list(Vars, VarList),
-    instmap_delta_no_output_vars_2(VarList, InstMap0, InstMapDelta, VT, M).
-
-:- pred instmap_delta_no_output_vars_2(list(prog_var)::in, instmap::in,
-    instmapping::in, vartypes::in, module_info::in) is semidet.
-
-instmap_delta_no_output_vars_2([], _, _, _, _).
-instmap_delta_no_output_vars_2([Var | Vars], InstMap0, InstMapDelta, VarTypes,
-        ModuleInfo) :-
+instmap_delta_no_output_vars(ModuleInfo, VarTypes, InstMap0, InstMapDelta,
+        Vars) :-
+    (
+        InstMapDelta = unreachable
+    ;
+        InstMapDelta = reachable(InstMapDeltaMap),
+        Test = var_is_not_output(ModuleInfo, VarTypes, InstMap0,
+            InstMapDeltaMap),
+        set_of_var.all_true(Test, Vars)
+    ).
+
+:- pred var_is_not_output(module_info::in, vartypes::in,
+    instmap::in, instmapping::in, prog_var::in) is semidet.
+
+var_is_not_output(ModuleInfo, VarTypes, InstMap0, InstMapDeltaMap, Var) :-
     instmap_lookup_var(InstMap0, Var, OldInst),
-    ( map.search(InstMapDelta, Var, NewInst) ->
+    ( map.search(InstMapDeltaMap, Var, NewInst) ->
         % We use `inst_matches_binding' to check that the new inst has only
         % added information or lost uniqueness, not bound anything.
         % If the instmap delta contains the variable, the variable may still
@@ -1261,9 +1266,7 @@
         % If the instmap delta doesn't contain the variable, it may still
         % have been (partially) output, if its inst is (or contains) `any'.
         not inst_contains_any(ModuleInfo, OldInst)
-    ),
-    instmap_delta_no_output_vars_2(Vars, InstMap0, InstMapDelta, VarTypes,
-        ModuleInfo).
+    ).
 
 %-----------------------------------------------------------------------------%
 %-----------------------------------------------------------------------------%
Index: compiler/set_of_var.m
===================================================================
RCS file: /home/mercury/mercury1/repository/mercury/compiler/set_of_var.m,v
retrieving revision 1.6
diff -u -b -r1.6 set_of_var.m
--- compiler/set_of_var.m	12 Oct 2011 00:38:19 -0000	1.6
+++ compiler/set_of_var.m	24 Apr 2012 06:49:15 -0000
@@ -141,6 +141,12 @@
 :- pred filter(pred(var(T))::in(pred(in) is semidet),
     set_of_var(T)::in, set_of_var(T)::out, set_of_var(T)::out) is det.
 
+    % all_true(Pred, Set) succeeds iff Pred(Element) succeeds
+    % for all the elements of Set.
+    %
+:- pred all_true(pred(var(T))::in(pred(in) is semidet), set_of_var(T)::in)
+    is semidet.
+
 %---------------
 % Graph colouring.
 
@@ -341,6 +347,9 @@
 filter(P, Set, Trues, Falses) :-
      tree_bitset.filter(P, Set, Trues, Falses).                     % MODULE
 
+all_true(P, Set) :-
+     tree_bitset.all_true(P, Set).                                  % MODULE
+
 %---------------
 % Graph colouring.
 
cvs diff: Diffing compiler/notes
cvs diff: Diffing deep_profiler
cvs diff: Diffing deep_profiler/notes
cvs diff: Diffing doc
cvs diff: Diffing extras
cvs diff: Diffing extras/base64
cvs diff: Diffing extras/cgi
cvs diff: Diffing extras/complex_numbers
cvs diff: Diffing extras/complex_numbers/samples
cvs diff: Diffing extras/complex_numbers/tests
cvs diff: Diffing extras/curs
cvs diff: Diffing extras/curs/samples
cvs diff: Diffing extras/curses
cvs diff: Diffing extras/curses/sample
cvs diff: Diffing extras/dynamic_linking
cvs diff: Diffing extras/error
cvs diff: Diffing extras/fixed
cvs diff: Diffing extras/gator
cvs diff: Diffing extras/gator/generations
cvs diff: Diffing extras/gator/generations/1
cvs diff: Diffing extras/graphics
cvs diff: Diffing extras/graphics/easyx
cvs diff: Diffing extras/graphics/easyx/samples
cvs diff: Diffing extras/graphics/mercury_allegro
cvs diff: Diffing extras/graphics/mercury_allegro/examples
cvs diff: Diffing extras/graphics/mercury_allegro/samples
cvs diff: Diffing extras/graphics/mercury_allegro/samples/demo
cvs diff: Diffing extras/graphics/mercury_allegro/samples/mandel
cvs diff: Diffing extras/graphics/mercury_allegro/samples/pendulum2
cvs diff: Diffing extras/graphics/mercury_allegro/samples/speed
cvs diff: Diffing extras/graphics/mercury_cairo
cvs diff: Diffing extras/graphics/mercury_cairo/samples
cvs diff: Diffing extras/graphics/mercury_cairo/samples/data
cvs diff: Diffing extras/graphics/mercury_cairo/tutorial
cvs diff: Diffing extras/graphics/mercury_glfw
cvs diff: Diffing extras/graphics/mercury_glfw/samples
cvs diff: Diffing extras/graphics/mercury_glut
cvs diff: Diffing extras/graphics/mercury_opengl
cvs diff: Diffing extras/graphics/mercury_tcltk
cvs diff: Diffing extras/graphics/samples
cvs diff: Diffing extras/graphics/samples/calc
cvs diff: Diffing extras/graphics/samples/gears
cvs diff: Diffing extras/graphics/samples/maze
cvs diff: Diffing extras/graphics/samples/pent
cvs diff: Diffing extras/lazy_evaluation
cvs diff: Diffing extras/lex
cvs diff: Diffing extras/lex/samples
cvs diff: Diffing extras/lex/tests
cvs diff: Diffing extras/log4m
cvs diff: Diffing extras/logged_output
cvs diff: Diffing extras/monte
cvs diff: Diffing extras/moose
cvs diff: Diffing extras/moose/samples
cvs diff: Diffing extras/moose/tests
cvs diff: Diffing extras/mopenssl
cvs diff: Diffing extras/morphine
cvs diff: Diffing extras/morphine/non-regression-tests
cvs diff: Diffing extras/morphine/scripts
cvs diff: Diffing extras/morphine/source
cvs diff: Diffing extras/net
cvs diff: Diffing extras/odbc
cvs diff: Diffing extras/posix
cvs diff: Diffing extras/posix/samples
cvs diff: Diffing extras/quickcheck
cvs diff: Diffing extras/quickcheck/tutes
cvs diff: Diffing extras/references
cvs diff: Diffing extras/references/samples
cvs diff: Diffing extras/references/tests
cvs diff: Diffing extras/solver_types
cvs diff: Diffing extras/solver_types/library
cvs diff: Diffing extras/trailed_update
cvs diff: Diffing extras/trailed_update/samples
cvs diff: Diffing extras/trailed_update/tests
cvs diff: Diffing extras/windows_installer_generator
cvs diff: Diffing extras/windows_installer_generator/sample
cvs diff: Diffing extras/windows_installer_generator/sample/images
cvs diff: Diffing extras/xml
cvs diff: Diffing extras/xml/samples
cvs diff: Diffing extras/xml_stylesheets
cvs diff: Diffing java
cvs diff: Diffing java/runtime
cvs diff: Diffing library
Index: library/fat_sparse_bitset.m
===================================================================
RCS file: /home/mercury/mercury1/repository/mercury/library/fat_sparse_bitset.m,v
retrieving revision 1.2
diff -u -b -r1.2 fat_sparse_bitset.m
--- library/fat_sparse_bitset.m	2 Apr 2012 03:58:55 -0000	1.2
+++ library/fat_sparse_bitset.m	24 Apr 2012 07:21:00 -0000
@@ -313,6 +313,12 @@
 :- mode foldr2(pred(in, in, out, in, out) is cc_multi, in, in, out, in, out)
     is cc_multi.
 
+    % all_true(Pred, Set) succeeds iff Pred(Element) succeeds
+    % for all the elements of Set.
+    %
+:- pred all_true(pred(T)::in(pred(in) is semidet), fat_sparse_bitset(T)::in)
+    is semidet <= enum(T).
+
     % `filter(Pred, Set) = TrueSet' returns the elements of Set for which
     % Pred succeeds.
     %
@@ -690,6 +696,51 @@
 
 %-----------------------------------------------------------------------------%
 
+all_true(P, fat_sparse_bitset(Set)) :-
+    all_true_node(P, Set).
+
+:- pred all_true_node(pred(T)::in(pred(in) is semidet), fat_bitset_impl::in)
+    is semidet <= enum(T).
+:- pragma type_spec(all_true_node/2, T = int).
+:- pragma type_spec(all_true_node/2, T = var(_)).
+
+all_true_node(_, empty).
+all_true_node(P, node(Offset, Bits, Rest)) :-
+    all_true_bits(P, Offset, Bits, bits_per_int),
+    all_true_node(P, Rest).
+
+:- pred all_true_bits(pred(T)::in(pred(in) is semidet),
+    int::in, int::in, int::in) is semidet <= enum(T).
+:- pragma type_spec(all_true_bits/4, T = int).
+:- pragma type_spec(all_true_bits/4, T = var(_)).
+
+all_true_bits(P, Offset, Bits, Size) :-
+    ( Bits = 0 ->
+        true
+    ; Size = 1 ->
+        ( Elem = from_int(Offset) ->
+            P(Elem)
+        ;
+            % We only apply `from_int/1' to integers returned
+            % by `to_int/1', so it should never fail.
+            unexpected($module, $pred, "`enum.from_int/1' failed")
+        )
+    ;
+        HalfSize = unchecked_right_shift(Size, 1),
+        Mask = mask(HalfSize),
+
+        % Extract the low-order half of the bits.
+        LowBits = Mask /\ Bits,
+
+        % Extract the high-order half of the bits.
+        HighBits = Mask /\ unchecked_right_shift(Bits, HalfSize),
+
+        all_true_bits(P, Offset, LowBits, HalfSize),
+        all_true_bits(P, Offset + HalfSize, HighBits, HalfSize)
+    ).
+
+%-----------------------------------------------------------------------------%
+
 % XXX We should make these more efficient.
 
 filter(Pred, Set) = TrueSet :-
Index: library/set.m
===================================================================
RCS file: /home/mercury/mercury1/repository/mercury/library/set.m,v
retrieving revision 1.98
diff -u -b -r1.98 set.m
--- library/set.m	2 Apr 2012 03:58:55 -0000	1.98
+++ library/set.m	24 Apr 2012 07:28:12 -0000
@@ -373,6 +373,11 @@
     pred(in, in, out, in, out, in, out, in, out, in, out, di, uo) is semidet,
     in, in, out, in, out, in, out, in, out, in, out, di, uo) is semidet.
 
+    % all_true(Pred, Set) succeeds iff Pred(Element) succeeds
+    % for all the elements of Set.
+    %
+:- pred all_true(pred(T)::in(pred(in) is semidet), set(T)::in) is semidet.
+
     % set.divide(Pred, Set, TruePart, FalsePart):
     % TruePart consists of those elements of Set for which Pred succeeds;
     % FalsePart consists of those elements of Set for which Pred fails.
@@ -625,6 +630,9 @@
 set.fold6(F, S, !A, !B, !C, !D, !E, !F) :-
     set_ordlist.fold6(F, S, !A, !B, !C, !D, !E, !F).
 
+set.all_true(P, S) :-
+    set_ordlist.all_true(P, S).
+
 set.divide(P, Set, TruePart, FalsePart) :-
     set_ordlist.divide(P, Set, TruePart, FalsePart).
 
Index: library/set_bbbtree.m
===================================================================
RCS file: /home/mercury/mercury1/repository/mercury/library/set_bbbtree.m,v
retrieving revision 1.41
diff -u -b -r1.41 set_bbbtree.m
--- library/set_bbbtree.m	2 Apr 2012 03:58:55 -0000	1.41
+++ library/set_bbbtree.m	24 Apr 2012 07:27:32 -0000
@@ -383,6 +383,12 @@
     pred(in, in, out, in, out, in, out, in, out, in, out, di, uo) is semidet,
     in, in, out, in, out, in, out, in, out, in, out, di, uo) is semidet.
 
+    % all_true(Pred, Set) succeeds iff Pred(Element) succeeds
+    % for all the elements of Set.
+    %
+:- pred all_true(pred(T)::in(pred(in) is semidet), set_bbbtree(T)::in)
+    is semidet.
+
 :- func set_bbbtree.map(func(T1) = T2, set_bbbtree(T1)) = set_bbbtree(T2).
 
 :- func set_bbbtree.filter_map(func(T1) = T2, set_bbbtree(T1))
@@ -1381,6 +1387,12 @@
 
 %--------------------------------------------------------------------------%
 
+set_bbbtree.all_true(P, S) :-
+    set_bbbtree.to_sorted_list(S, L),
+    list.all_true(P, L).
+
+%--------------------------------------------------------------------------%
+
 set_bbbtree.map(F, S1) = S2 :-
     set_bbbtree.to_sorted_list(S1, L1),
     L2 = list.map(F, L1),
Index: library/set_ctree234.m
===================================================================
RCS file: /home/mercury/mercury1/repository/mercury/library/set_ctree234.m,v
retrieving revision 1.18
diff -u -b -r1.18 set_ctree234.m
--- library/set_ctree234.m	2 Apr 2012 03:58:56 -0000	1.18
+++ library/set_ctree234.m	24 Apr 2012 08:05:29 -0000
@@ -345,6 +345,12 @@
     pred(in, in, out, in, out, in, out, in, out, in, out, di, uo) is semidet,
     in, in, out, in, out, in, out, in, out, in, out, di, uo) is semidet.
 
+    % all_true(Pred, Set) succeeds iff Pred(Element) succeeds
+    % for all the elements of Set.
+    %
+:- pred set_ctree234.all_true(pred(T)::in(pred(in) is semidet),
+    set_ctree234(T)::in) is semidet.
+
     % Return the set of items for which the predicate succeeds.
     %
 :- pred set_ctree234.filter(pred(T)::in(pred(in) is semidet),
@@ -2925,6 +2931,40 @@
 
 %------------------------------------------------------------------------------%
 
+set_ctree234.all_true(Pred, ct(_, T)) :-
+    set_ctree234.all_true_tree(Pred, T).
+
+:- pred set_ctree234.all_true_tree(pred(T)::in(pred(in) is semidet),
+    set_tree234(T)::in) is semidet.
+
+set_ctree234.all_true_tree(Pred, T) :-
+    (
+        T = empty
+    ;
+        T = two(E0, T0, T1),
+        set_ctree234.all_true_tree(Pred, T0),
+        Pred(E0),
+        set_ctree234.all_true_tree(Pred, T1)
+    ;
+        T = three(E0, E1, T0, T1, T2),
+        set_ctree234.all_true_tree(Pred, T0),
+        Pred(E0),
+        set_ctree234.all_true_tree(Pred, T1),
+        Pred(E1),
+        set_ctree234.all_true_tree(Pred, T2)
+    ;
+        T = four(E0, E1, E2, T0, T1, T2, T3),
+        set_ctree234.all_true_tree(Pred, T0),
+        Pred(E0),
+        set_ctree234.all_true_tree(Pred, T1),
+        Pred(E1),
+        set_ctree234.all_true_tree(Pred, T2),
+        Pred(E2),
+        set_ctree234.all_true_tree(Pred, T3)
+    ).
+
+%------------------------------------------------------------------------------%
+
 set_ctree234.filter_map(Pred, ct(_, TreeA), SetB) :-
     set_ctree234.filter_map_pred(Pred, TreeA, [], ListB),
     SetB = set_ctree234.list_to_set(ListB).
Index: library/set_ordlist.m
===================================================================
RCS file: /home/mercury/mercury1/repository/mercury/library/set_ordlist.m,v
retrieving revision 1.44
diff -u -b -r1.44 set_ordlist.m
--- library/set_ordlist.m	2 Apr 2012 03:58:56 -0000	1.44
+++ library/set_ordlist.m	24 Apr 2012 07:38:27 -0000
@@ -361,6 +361,12 @@
     pred(in, in, out, in, out, in, out, in, out, in, out, di, uo) is semidet,
     in, in, out, in, out, in, out, in, out, in, out, di, uo) is semidet.
 
+    % all_true(Pred, Set) succeeds iff Pred(Element) succeeds
+    % for all the elements of Set.
+    %
+:- pred all_true(pred(T)::in(pred(in) is semidet), set_ordlist(T)::in)
+    is semidet.
+
     % set_ordlist.divide(Pred, Set, TruePart, FalsePart):
     % TruePart consists of those elements of Set for which Pred succeeds;
     % FalsePart consists of those elements of Set for which Pred fails.
@@ -741,6 +747,11 @@
 
 %-----------------------------------------------------------------------------%
 
+set_ordlist.all_true(P, sol(L)) :-
+    list.all_true(P, L).
+
+%-----------------------------------------------------------------------------%
+
 set_ordlist.filter(P, Set) = TrueSet :-
     List = set_ordlist.to_sorted_list(Set),
     list.filter(P, List, TrueList),
Index: library/set_tree234.m
===================================================================
RCS file: /home/mercury/mercury1/repository/mercury/library/set_tree234.m,v
retrieving revision 1.21
diff -u -b -r1.21 set_tree234.m
--- library/set_tree234.m	2 Apr 2012 03:58:56 -0000	1.21
+++ library/set_tree234.m	24 Apr 2012 07:54:50 -0000
@@ -350,6 +350,12 @@
     pred(in, in, out, in, out, in, out, in, out, in, out, di, uo) is semidet,
     in, in, out, in, out, in, out, in, out, in, out, di, uo) is semidet.
 
+    % all_true(Pred, Set) succeeds iff Pred(Element) succeeds
+    % for all the elements of Set.
+    %
+:- pred set_tree234.all_true(pred(T)::in(pred(in) is semidet),
+    set_tree234(T)::in) is semidet.
+
     % Return the set of items for which the predicate succeeds.
     %
 :- func set_tree234.filter(pred(T)::in(pred(in) is semidet),
@@ -2540,6 +2546,34 @@
 
 %------------------------------------------------------------------------------%
 
+set_tree234.all_true(Pred, T) :-
+    (
+        T = empty
+    ;
+        T = two(E0, T0, T1),
+        set_tree234.all_true(Pred, T0),
+        Pred(E0),
+        set_tree234.all_true(Pred, T1)
+    ;
+        T = three(E0, E1, T0, T1, T2),
+        set_tree234.all_true(Pred, T0),
+        Pred(E0),
+        set_tree234.all_true(Pred, T1),
+        Pred(E1),
+        set_tree234.all_true(Pred, T2)
+    ;
+        T = four(E0, E1, E2, T0, T1, T2, T3),
+        set_tree234.all_true(Pred, T0),
+        Pred(E0),
+        set_tree234.all_true(Pred, T1),
+        Pred(E1),
+        set_tree234.all_true(Pred, T2),
+        Pred(E2),
+        set_tree234.all_true(Pred, T3)
+    ).
+
+%------------------------------------------------------------------------------%
+
 set_tree234.map(Pred, SetA, SetB) :-
     set_tree234.map_pred(Pred, SetA, [], ListB),
     SetB = set_tree234.list_to_set(ListB).
Index: library/set_unordlist.m
===================================================================
RCS file: /home/mercury/mercury1/repository/mercury/library/set_unordlist.m,v
retrieving revision 1.40
diff -u -b -r1.40 set_unordlist.m
--- library/set_unordlist.m	2 Apr 2012 03:58:56 -0000	1.40
+++ library/set_unordlist.m	24 Apr 2012 08:07:48 -0000
@@ -358,6 +358,12 @@
     pred(in, in, out, in, out, in, out, in, out, in, out, di, uo) is semidet,
     in, in, out, in, out, in, out, in, out, in, out, di, uo) is semidet.
 
+    % all_true(Pred, Set) succeeds iff Pred(Element) succeeds
+    % for all the elements of Set.
+    %
+:- pred set_unordlist.all_true(pred(T)::in(pred(in) is semidet),
+    set_unordlist(T)::in) is semidet.
+
     % Return the set of items for which the predicate succeeds.
     %
 :- pred set_unordlist.filter(pred(T)::in(pred(in) is semidet),
@@ -574,6 +580,11 @@
     list.foldl6(P, set_unordlist.to_sorted_list(S), !A, !B, !C, !D, !E, !F).
 
 %-----------------------------------------------------------------------------%
+
+set_unordlist.all_true(P, sul(L)) :-
+    list.all_true(P, L).
+
+%-----------------------------------------------------------------------------%
 %-----------------------------------------------------------------------------%
 % Ralph Becket <rwab1 at cam.sri.com> 24/04/99
 %   Function forms added.
Index: library/sparse_bitset.m
===================================================================
RCS file: /home/mercury/mercury1/repository/mercury/library/sparse_bitset.m,v
retrieving revision 1.43
diff -u -b -r1.43 sparse_bitset.m
--- library/sparse_bitset.m	2 Apr 2012 03:58:56 -0000	1.43
+++ library/sparse_bitset.m	24 Apr 2012 08:14:54 -0000
@@ -328,6 +328,12 @@
 :- mode foldr2(pred(in, in, out, in, out) is cc_multi, in, in, out, in, out)
     is cc_multi.
 
+    % all_true(Pred, Set) succeeds iff Pred(Element) succeeds
+    % for all the elements of Set.
+    %
+:- pred all_true(pred(T)::in(pred(in) is semidet), sparse_bitset(T)::in)
+    is semidet <= enum(T).
+
     % `filter(Pred, Set) = TrueSet' returns the elements of Set for which
     % Pred succeeds.
     %
@@ -706,6 +712,51 @@
 
 %-----------------------------------------------------------------------------%
 
+all_true(P, sparse_bitset(Set)) :-
+    all_true_node(P, Set).
+
+:- pred all_true_node(pred(T)::in(pred(in) is semidet), bitset_impl::in)
+    is semidet <= enum(T).
+:- pragma type_spec(all_true_node/2, T = int).
+:- pragma type_spec(all_true_node/2, T = var(_)).
+
+all_true_node(_, []).
+all_true_node(P, [bitset_elem(Offset, Bits) | Rest]) :-
+    all_true_bits(P, Offset, Bits, bits_per_int),
+    all_true_node(P, Rest).
+
+:- pred all_true_bits(pred(T)::in(pred(in) is semidet),
+    int::in, int::in, int::in) is semidet <= enum(T).
+:- pragma type_spec(all_true_bits/4, T = int).
+:- pragma type_spec(all_true_bits/4, T = var(_)).
+
+all_true_bits(P, Offset, Bits, Size) :-
+    ( Bits = 0 ->
+        true
+    ; Size = 1 ->
+        ( Elem = from_int(Offset) ->
+            P(Elem)
+        ;
+            % We only apply `from_int/1' to integers returned
+            % by `to_int/1', so it should never fail.
+            unexpected($module, $pred, "`enum.from_int/1' failed")
+        )
+    ;
+        HalfSize = unchecked_right_shift(Size, 1),
+        Mask = mask(HalfSize),
+
+        % Extract the low-order half of the bits.
+        LowBits = Mask /\ Bits,
+
+        % Extract the high-order half of the bits.
+        HighBits = Mask /\ unchecked_right_shift(Bits, HalfSize),
+
+        all_true_bits(P, Offset, LowBits, HalfSize),
+        all_true_bits(P, Offset + HalfSize, HighBits, HalfSize)
+    ).
+
+%-----------------------------------------------------------------------------%
+
 % XXX We should make these more efficient.
 
 filter(Pred, Set) = TrueSet :-
Index: library/test_bitset.m
===================================================================
RCS file: /home/mercury/mercury1/repository/mercury/library/test_bitset.m,v
retrieving revision 1.2
diff -u -b -r1.2 test_bitset.m
--- library/test_bitset.m	2 Apr 2012 03:58:56 -0000	1.2
+++ library/test_bitset.m	24 Apr 2012 08:22:45 -0000
@@ -128,6 +128,12 @@
 :- func foldl(func(T, Acc) = Acc, test_bitset(T), Acc) = Acc <= enum(T).
 :- mode foldl(func(in, in) = out is det, in, in) = out is det.
 
+    % all_true(Pred, Set) succeeds iff Pred(Element) succeeds
+    % for all the elements of Set.
+    %
+:- pred all_true(pred(T)::in(pred(in) is semidet), test_bitset(T)::in)
+    is semidet <= enum(T).
+
 :- func filter(pred(T)::in(pred(in) is semidet), test_bitset(T)::in)
     = (test_bitset(T)::out) is det <= enum(T).
 :- pred filter(pred(T)::in(pred(in) is semidet),
@@ -512,6 +518,21 @@
         unexpected($module, $pred, "failed")
     ).
 
+all_true(Pred, SetA - SetB) :-
+    ( tree_bitset.all_true(Pred, SetA) ->
+        ( set_ordlist.all_true(Pred, SetB) ->
+            true
+        ;
+            unexpected($module, $pred, "tree_bitset but not set_ordlist")
+        )
+    ;
+        ( set_ordlist.all_true(Pred, SetB) ->
+            unexpected($module, $pred, "set_ordlist but not tree_bitset")
+        ;
+            fail
+        )
+    ).
+
 filter(Pred, SetA - SetB) = Result :-
     tree_bitset.to_sorted_list(SetA, SetListA),
     set_ordlist.to_sorted_list(SetB, SetListB),
Index: library/tree_bitset.m
===================================================================
RCS file: /home/mercury/mercury1/repository/mercury/library/tree_bitset.m,v
retrieving revision 1.19
diff -u -b -r1.19 tree_bitset.m
--- library/tree_bitset.m	23 Apr 2012 00:19:25 -0000	1.19
+++ library/tree_bitset.m	24 Apr 2012 07:14:42 -0000
@@ -315,6 +315,12 @@
 :- mode foldr2(pred(in, in, out, in, out) is cc_multi, in, in, out, in, out)
     is cc_multi.
 
+    % all_true(Pred, Set) succeeds iff Pred(Element) succeeds
+    % for all the elements of Set.
+    %
+:- pred all_true(pred(T)::in(pred(in) is semidet), tree_bitset(T)::in)
+    is semidet <= enum(T).
+
     % `filter(Pred, Set) = TrueSet' returns the elements of Set for which
     % Pred succeeds.
     %
@@ -419,6 +425,9 @@
 :- pragma type_spec(foldr/4, T = int).
 :- pragma type_spec(foldr/4, T = var(_)).
 
+:- pragma type_spec(all_true/2, T = int).
+:- pragma type_spec(all_true/2, T = var(_)).
+
 %-----------------------------------------------------------------------------%
 %-----------------------------------------------------------------------------%
 
@@ -4040,3 +4049,71 @@
             fold2_bits(Dir, P, Offset, LowBits, HalfSize, !AccA, !AccB)
         )
     ).
+
+%-----------------------------------------------------------------------------%
+
+all_true(P, Set) :-
+    Set = tree_bitset(List),
+    (
+        List = leaf_list(LeafNodes),
+        leaf_all_true(P, LeafNodes)
+    ;
+        List = interior_list(_, InteriorNodes),
+        interior_all_true(P, InteriorNodes)
+    ).
+
+:- pred interior_all_true(pred(T)::in(pred(in) is semidet),
+    list(interior_node)::in) is semidet <= enum(T).
+:- pragma type_spec(interior_all_true/2, T = int).
+:- pragma type_spec(interior_all_true/2, T = var(_)).
+
+interior_all_true(_P, []).
+interior_all_true(P, [H | T]) :-
+    Components = H ^ components,
+    (
+        Components = leaf_list(LeafNodes),
+        leaf_all_true(P, LeafNodes)
+    ;
+        Components = interior_list(_, InteriorNodes),
+        interior_all_true(P, InteriorNodes)
+    ),
+    interior_all_true(P, T).
+
+:- pred leaf_all_true(pred(T)::in(pred(in) is semidet), list(leaf_node)::in)
+    is semidet <= enum(T).
+:- pragma type_spec(leaf_all_true/2, T = int).
+:- pragma type_spec(leaf_all_true/2, T = var(_)).
+
+leaf_all_true(_P, []).
+leaf_all_true(P, [H | T]) :-
+    all_true_bits(P, H ^ leaf_offset, H ^ leaf_bits, bits_per_int),
+    leaf_all_true(P, T).
+
+    % Do a binary search for the 1 bits in an int.
+    %
+:- pred all_true_bits(pred(T)::in(pred(in) is semidet),
+    int::in, int::in, int::in) is semidet <= enum(T).
+:- pragma type_spec(all_true_bits/4, T = int).
+:- pragma type_spec(all_true_bits/4, T = var(_)).
+
+all_true_bits(P, Offset, Bits, Size) :-
+    ( Bits = 0 ->
+        true
+    ; Size = 1 ->
+        Elem = index_to_enum(Offset),
+        P(Elem)
+    ;
+        HalfSize = unchecked_right_shift(Size, 1),
+        Mask = mask(HalfSize),
+
+        % Extract the low-order half of the bits.
+        LowBits = Mask /\ Bits,
+
+        % Extract the high-order half of the bits.
+        HighBits = Mask /\ unchecked_right_shift(Bits, HalfSize),
+
+        all_true_bits(P, Offset, LowBits, HalfSize),
+        all_true_bits(P, Offset + HalfSize, HighBits, HalfSize)
+    ).
+
+%-----------------------------------------------------------------------------%
cvs diff: Diffing m4
cvs diff: Diffing mdbcomp
cvs diff: Diffing profiler
cvs diff: Diffing robdd
cvs diff: Diffing runtime
cvs diff: Diffing runtime/GETOPT
cvs diff: Diffing runtime/machdeps
cvs diff: Diffing samples
cvs diff: Diffing samples/appengine
cvs diff: Diffing samples/appengine/war
cvs diff: Diffing samples/appengine/war/WEB-INF
cvs diff: Diffing samples/c_interface
cvs diff: Diffing samples/c_interface/c_calls_mercury
cvs diff: Diffing samples/c_interface/cplusplus_calls_mercury
cvs diff: Diffing samples/c_interface/mercury_calls_c
cvs diff: Diffing samples/c_interface/mercury_calls_cplusplus
cvs diff: Diffing samples/c_interface/mercury_calls_fortran
cvs diff: Diffing samples/c_interface/simpler_c_calls_mercury
cvs diff: Diffing samples/c_interface/simpler_cplusplus_calls_mercury
cvs diff: Diffing samples/c_interface/standalone_c
cvs diff: Diffing samples/concurrency
cvs diff: Diffing samples/concurrency/dining_philosophers
cvs diff: Diffing samples/concurrency/midimon
cvs diff: Diffing samples/diff
cvs diff: Diffing samples/java_interface
cvs diff: Diffing samples/java_interface/java_calls_mercury
cvs diff: Diffing samples/java_interface/mercury_calls_java
cvs diff: Diffing samples/lazy_list
cvs diff: Diffing samples/muz
cvs diff: Diffing samples/rot13
cvs diff: Diffing samples/solutions
cvs diff: Diffing samples/solver_types
cvs diff: Diffing samples/tests
cvs diff: Diffing samples/tests/c_interface
cvs diff: Diffing samples/tests/c_interface/c_calls_mercury
cvs diff: Diffing samples/tests/c_interface/cplusplus_calls_mercury
cvs diff: Diffing samples/tests/c_interface/mercury_calls_c
cvs diff: Diffing samples/tests/c_interface/mercury_calls_cplusplus
cvs diff: Diffing samples/tests/c_interface/mercury_calls_fortran
cvs diff: Diffing samples/tests/c_interface/simpler_c_calls_mercury
cvs diff: Diffing samples/tests/c_interface/simpler_cplusplus_calls_mercury
cvs diff: Diffing samples/tests/diff
cvs diff: Diffing samples/tests/muz
cvs diff: Diffing samples/tests/rot13
cvs diff: Diffing samples/tests/solutions
cvs diff: Diffing samples/tests/toplevel
cvs diff: Diffing scripts
cvs diff: Diffing slice
cvs diff: Diffing ssdb
cvs diff: Diffing tests
cvs diff: Diffing tests/analysis
cvs diff: Diffing tests/analysis/ctgc
cvs diff: Diffing tests/analysis/excp
cvs diff: Diffing tests/analysis/ext
cvs diff: Diffing tests/analysis/sharing
cvs diff: Diffing tests/analysis/table
cvs diff: Diffing tests/analysis/trail
cvs diff: Diffing tests/analysis/unused_args
cvs diff: Diffing tests/benchmarks
cvs diff: Diffing tests/debugger
cvs diff: Diffing tests/debugger/declarative
cvs diff: Diffing tests/dppd
cvs diff: Diffing tests/feedback
cvs diff: Diffing tests/feedback/mandelbrot
cvs diff: Diffing tests/feedback/mmc
cvs diff: Diffing tests/general
cvs diff: Diffing tests/general/accumulator
cvs diff: Diffing tests/general/string_format
cvs diff: Diffing tests/general/structure_reuse
cvs diff: Diffing tests/grade_subdirs
cvs diff: Diffing tests/hard_coded
cvs diff: Diffing tests/hard_coded/exceptions
cvs diff: Diffing tests/hard_coded/purity
cvs diff: Diffing tests/hard_coded/sub-modules
cvs diff: Diffing tests/hard_coded/typeclasses
cvs diff: Diffing tests/invalid
cvs diff: Diffing tests/invalid/purity
cvs diff: Diffing tests/misc_tests
cvs diff: Diffing tests/mmc_make
cvs diff: Diffing tests/mmc_make/lib
cvs diff: Diffing tests/par_conj
cvs diff: Diffing tests/recompilation
cvs diff: Diffing tests/stm
cvs diff: Diffing tests/stm/orig
cvs diff: Diffing tests/stm/orig/stm-compiler
cvs diff: Diffing tests/stm/orig/stm-compiler/test1
cvs diff: Diffing tests/stm/orig/stm-compiler/test10
cvs diff: Diffing tests/stm/orig/stm-compiler/test2
cvs diff: Diffing tests/stm/orig/stm-compiler/test3
cvs diff: Diffing tests/stm/orig/stm-compiler/test4
cvs diff: Diffing tests/stm/orig/stm-compiler/test5
cvs diff: Diffing tests/stm/orig/stm-compiler/test6
cvs diff: Diffing tests/stm/orig/stm-compiler/test7
cvs diff: Diffing tests/stm/orig/stm-compiler/test8
cvs diff: Diffing tests/stm/orig/stm-compiler/test9
cvs diff: Diffing tests/stm/orig/stm-compiler-par
cvs diff: Diffing tests/stm/orig/stm-compiler-par/bm1
cvs diff: Diffing tests/stm/orig/stm-compiler-par/bm2
cvs diff: Diffing tests/stm/orig/stm-compiler-par/stmqueue
cvs diff: Diffing tests/stm/orig/stm-compiler-par/test1
cvs diff: Diffing tests/stm/orig/stm-compiler-par/test10
cvs diff: Diffing tests/stm/orig/stm-compiler-par/test11
cvs diff: Diffing tests/stm/orig/stm-compiler-par/test2
cvs diff: Diffing tests/stm/orig/stm-compiler-par/test3
cvs diff: Diffing tests/stm/orig/stm-compiler-par/test4
cvs diff: Diffing tests/stm/orig/stm-compiler-par/test5
cvs diff: Diffing tests/stm/orig/stm-compiler-par/test6
cvs diff: Diffing tests/stm/orig/stm-compiler-par/test7
cvs diff: Diffing tests/stm/orig/stm-compiler-par/test8
cvs diff: Diffing tests/stm/orig/stm-compiler-par/test9
cvs diff: Diffing tests/stm/orig/stm-compiler-par-asm_fast
cvs diff: Diffing tests/stm/orig/stm-compiler-par-asm_fast/test1
cvs diff: Diffing tests/stm/orig/stm-compiler-par-asm_fast/test2
cvs diff: Diffing tests/stm/orig/stm-compiler-par-asm_fast/test3
cvs diff: Diffing tests/stm/orig/stm-compiler-par-asm_fast/test4
cvs diff: Diffing tests/stm/orig/stm-compiler-par-asm_fast/test5
cvs diff: Diffing tests/stm/orig/stm-compiler-par-asm_fast/test6
cvs diff: Diffing tests/stm/orig/stm-compiler-par-asm_fast/test7
cvs diff: Diffing tests/stm/orig/stm-compiler-par-asm_fast/test8
cvs diff: Diffing tests/stm/orig/stm-compiler-par-asm_fast/test9
cvs diff: Diffing tests/tabling
cvs diff: Diffing tests/term
cvs diff: Diffing tests/trailing
cvs diff: Diffing tests/valid
cvs diff: Diffing tests/warnings
cvs diff: Diffing tools
cvs diff: Diffing trace
cvs diff: Diffing util
cvs diff: Diffing vim
cvs diff: Diffing vim/after
cvs diff: Diffing vim/ftplugin
cvs diff: Diffing vim/syntax
--------------------------------------------------------------------------
mercury-reviews mailing list
Post messages to:       mercury-reviews at csse.unimelb.edu.au
Administrative Queries: owner-mercury-reviews at csse.unimelb.edu.au
Subscriptions:          mercury-reviews-request at csse.unimelb.edu.au
--------------------------------------------------------------------------



More information about the reviews mailing list