[m-rev.] for review: configure .NET support in bindist configuration.

Tyson Dowd trd at cs.mu.OZ.AU
Tue Mar 13 19:07:22 AEDT 2001


On 13-Mar-2001, Fergus Henderson <fjh at cs.mu.OZ.AU> wrote:
> On 13-Mar-2001, Tyson Dowd <trd at cs.mu.OZ.AU> wrote:
> > bindist/bindist.configure.in:
> > 	Look for the .NET SDK on the machine which installs the bindist.
> > 	If it is present, substitute the appropriate configuration
> > 	variables, so that mmake can correctly build .NET components on this
> > 	system.
> 
> It would be better to put that check in a macro in aclocal.m4 rather than
> duplicating it in configure.in and bindist/bindist.configure.in.


===================================================================


Estimated hours taken: 0.4
Branches: main release

bindist/bindist.configure.in:
	Look for the .NET SDK on the machine which installs the bindist.
	If it is present, substitute the appropriate configuration
	variables, so that mmake can correctly build .NET components on this
	system.

aclocal.m4:
	Implement the dotnet checks here.

configure.in:
	Use the new implementation of the dotnet checks from aclocal.m4


Index: aclocal.m4
===================================================================
RCS file: /home/mercury1/repository/mercury/aclocal.m4,v
retrieving revision 1.3
diff -u -r1.3 aclocal.m4
--- aclocal.m4	1999/06/01 07:55:26	1.3
+++ aclocal.m4	2001/03/13 08:01:44
@@ -65,3 +65,30 @@
 ])
 
 #-----------------------------------------------------------------------------#
+#
+# Microsoft.NET configuration
+#
+AC_DEFUN(MERCURY_CHECK_DOTNET,
+[
+AC_PATH_PROG(ILASM, ilasm)
+
+AC_MSG_CHECKING(for Microsoft.NET Framework SDK)
+AC_CACHE_VAL(mercury_cv_microsoft_dotnet, [
+if test "$ILASM" != ""; then
+	changequote(<<,>>) 
+	MS_DOTNET_SDK_DIR=`expr "$ILASM" : '\(.*\)[/\\]*[bB]in[/\\]*ilasm'`
+	changequote([,]) 
+	mercury_cv_microsoft_dotnet="yes"
+else
+	MS_DOTNET_SDK_DIR=""
+	mercury_cv_microsoft_dotnet="no"
+fi
+])
+AC_MSG_RESULT($mercury_cv_microsoft_dotnet)
+ILASM=`basename "$ILASM"`
+
+AC_SUBST(ILASM)
+AC_SUBST(MS_DOTNET_SDK_DIR)
+])
+
+#-----------------------------------------------------------------------------#
Index: configure.in
===================================================================
RCS file: /home/mercury1/repository/mercury/configure.in,v
retrieving revision 1.249
diff -u -r1.249 configure.in
--- configure.in	2001/02/28 13:06:44	1.249
+++ configure.in	2001/03/13 08:02:42
@@ -428,25 +428,7 @@
 #-----------------------------------------------------------------------------#
 # Microsoft.NET configuration
 # 
-AC_PATH_PROG(ILASM, ilasm)
-
-AC_MSG_CHECKING(for Microsoft.NET Framework SDK)
-AC_CACHE_VAL(mercury_cv_microsoft_dotnet, [
-if test "$ILASM" != ""; then
-	changequote(<<,>>) 
-	MS_DOTNET_SDK_DIR=`expr "$ILASM" : '\(.*\)[/\\]*[bB]in[/\\]*ilasm'`
-	changequote([,]) 
-	mercury_cv_microsoft_dotnet="yes"
-else
-	MS_DOTNET_SDK_DIR=""
-	mercury_cv_microsoft_dotnet="no"
-fi
-])
-AC_MSG_RESULT($mercury_cv_microsoft_dotnet)
-ILASM=`basename "$ILASM"`
-
-AC_SUBST(ILASM)
-AC_SUBST(MS_DOTNET_SDK_DIR)
+MERCURY_CHECK_DOTNET
 
 #-----------------------------------------------------------------------------#
 # Don't try to use mprotect() on gnu-win32, since it is broken
Index: bindist/bindist.configure.in
===================================================================
RCS file: /home/mercury1/repository/mercury/bindist/bindist.configure.in,v
retrieving revision 1.30
diff -u -r1.30 bindist.configure.in
--- bindist/bindist.configure.in	2001/01/24 00:57:18	1.30
+++ bindist/bindist.configure.in	2001/03/13 08:02:19
@@ -198,6 +198,10 @@
 AC_PROG_CC
 AC_SUBST(CC)
 #-----------------------------------------------------------------------------#
+# Microsoft.NET configuration (the bindist may be installed on a machine
+# that supports .NET even if it was built on a machine that doesn't).
+# 
+MERCURY_CHECK_DOTNET
 
 # The following allows us to share some subroutines between the
 # `ml' and `mgnuc' scripts.


-- 
       Tyson Dowd           # 
                            #  Surreal humour isn't everyone's cup of fur.
     trd at cs.mu.oz.au        # 
http://www.cs.mu.oz.au/~trd #
--------------------------------------------------------------------------
mercury-reviews mailing list
post:  mercury-reviews at cs.mu.oz.au
administrative address: owner-mercury-reviews at cs.mu.oz.au
unsubscribe: Address: mercury-reviews-request at cs.mu.oz.au Message: unsubscribe
subscribe:   Address: mercury-reviews-request at cs.mu.oz.au Message: subscribe
--------------------------------------------------------------------------



More information about the reviews mailing list